Файл:COVID-19-Pandemie - NR (Nauru) - Infizierte (800px).svg
Размер этого PNG-превью для исходного SVG-файла: 800 × 450 пкс. Другие разрешения: 320 × 180 пкс | 640 × 360 пкс | 1024 × 576 пкс | 1280 × 720 пкс | 2560 × 1440 пкс.
Исходный файл (SVG-файл, номинально 800 × 450 пкс, размер файла: 465 КБ)
Этот файл находится на Викискладе. Сведения о нём показаны ниже.
Викисклад — централизованное хранилище для свободных файлов, используемых в проектах Викимедиа.
Сообщить об ошибке с файлом |
Краткое описание
ОписаниеCOVID-19-Pandemie - NR (Nauru) - Infizierte (800px).svg |
Deutsch: COVID-19-Pandemie - NR (Nauru) - Infizierte (800px) |
||
Дата | laufende Aktualisierungen | ||
Источник | Daten von der WHO - https://covid19.who.int/WHO-COVID-19-global-data.csv - durch Klicken auffindbar über https://covid19.who.int/table | ||
Автор | Summer ... hier! | ||
SVG‑разработка InfoField | |||
Исходный код InfoField |
# input (Zeitformat und Separator definieren)
#
set timefmt "%Y-%m-%d"
set datafile separator ';'
# Variablen zeile_X_stat setzten
# (every ::0 steht für 'ab erster Zeile' und kann weggelassen werden)
stats $WHO_data every ::0 using 5 name "zeile_5_stat" nooutput
stats $WHO_data every ::0 using 6 name "zeile_6_stat" nooutput
stats $WHO_data every ::0 using 7 name "zeile_7_stat" nooutput
stats $WHO_data every ::0 using 8 name "zeile_8_stat" nooutput
# Start und Ende ermitteln und Label setzen (incl. Konsolenausgabe)
stats $WHO_data every ::0 u (strptime("%Y-%m-%d",strcol(1))) name "datum" nooutput
print ' -----Stats-(Timestamp)----'
print ' Start: ', strftime("%d. %B %Y",datum_min)
print ' Ende: ', strftime("%d. %B %Y",datum_max)
print ' --------------------------'
# label fuer Grafikueberschrtft oben links mit den ermittelten Werten setzen
set label 'Daten vom '.strftime("%d.%m.%y",datum_min).' bis '.strftime("%d.%m.%y",datum_max) at graph 0.03, graph 0.93
# als Workaround nehmen wir statt zweimal 'ylabel' hier zweimal 'label'
# (bei multiplot ist es schwierig fuer alle Plots ein ylabel mit gleichen seitl. Einzug zu finden)
set label "Infizierte (kumuliert)" at screen 0.017, 0.700 rotate by +90 center
set label "Neuinfektionen" at screen 0.017, 0.300 rotate by +90 center
# output
#
# Name der SVG-Datei
set output 'COVID-19-Pandemie_-_NR_(Nauru)_-_Infizierte_(800px).svg'
unset key # keine Box fuer Legende
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set xtics scale 0.7, 0.4 # Skalenstriche x-Achse etwas kleiner
set ytics scale 0.7, 0.4 # Skalenstriche y-Achse etwas kleiner
set ytics offset 0.4, 0.0 # Zahlen eine Idee nach rechts (mehr Abstand vom Label)
# 'Wasserzeichen' für commonsprüfung
set label 'NR' at screen 0.01, 0.02 textcolor rgb '#ffffff' font 'Arial,8'
# Gitterlinienen per Hand setzen
set style line 1 linetype rgb '#4f4f4f' linewidth 0.25 # Def. Major-grid
set style line 2 linetype rgb '#9f9f9f' linewidth 0.20 # def. Minor-grid
unset grid
set grid noxtics nomxtics # Keine Gitterlinen an der 1. X-Achse (Monate)
set grid x2tics nomx2tics # Gitterliniene an der 2. X-Achse (Kalenderwochen)
set grid ytics mytics # Gitterl. an der Y-Achse
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle fuer Major u. Minor
# X-Achsenbeschriftung:
# ueber x1 machen wir die Monatsbschriftung, ueber x2 die Kalenderwochenbeschriftung
#
# beide X-Achsen, also x1 und x2, als Zeitachse definieren
set xdata time
set x2data time
# Bereich (von - bis) der X-Achse definieren
# Beginnt am 1. Jan. 2020 und Edit heute plus 6 Tage
xrange_max=strftime("%Y-%m-%d", time(0) + (60*60*24*6))
# zuvor Berechnetes xrange_max setzten
set xrange ['2020-01-01': xrange_max]
set x2range ['2020-01-01': xrange_max]
# die Maker fuer Monat setzen wir per Hand. Als 'format' geben wir einen leeren String an damit
# kein Text generiert wird (fuer die untere Grafik setzen wir den Text spaeter)
set xtics format "" # Format auf Nichts damit gnuplot die folgenden Daten nicht aufloest
set xtics ( "2020-01-01" \
, "2020-02-01" \
, "2020-03-01" \
, "2020-04-01" \
, "2020-05-01" \
, "2020-06-01" \
, "2020-07-01" \
, "2020-08-01" \
, "2020-09-01" \
, "2020-10-01" \
, "2020-11-01" \
, "2020-12-01" \
, "2021-01-01" \
, "2021-02-01" \
, "2021-03-01" \
)
#
# Kalenderwochen-Striche
#
# fuer x2 (KW) ebendalls keine Beschriftung
set format x2 ''
# der 6. Jan. 2020 war ein Montag - da setzen wir den ersten Strich und die
# folgenden Striche alle 7 Tage (hier in 60 * 60 * 24 * 7 Sekunden)
set x2tics '2020-01-06', 60 * 60 * 24 * 7
set x2tics scale 0
set xtics nomirror
unset mxtics
# Format Y-Achse
set decimalsign locale "de_DE.utf8"
set format y "%'.0f"
set yrange [-2:10]
set ytics 10
set mytics 5
set ytics nomirror
# Zebramuster
set style rect fillcolor lt -1 fillstyle solid 0.06 noborder
do for [i=1:12:2] {
marker_start=sprintf("2020-%1.2d-01",i)
marker_stop =sprintf("2020-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
marker_start=sprintf("2021-%1.2d-01",i)
marker_stop =sprintf("2021-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
}
# Groesse und Schrift definieren
#
# Zur Variablen 'datum_max' siehe oben
my_svg_name=strftime("COVID_%d_%m_%Y_NR",datum_max)
set term svg size 800,450 font "Arial,16" name my_svg_name
###########################################################################################
set lmargin 10.0 # linker Rand fuer Beschriftung Y-Achse sollte nicht auf Auto stehen
set rmargin 1.0 # rechter Rand
set tmargin 1.0 # top margin
set bmargin 0.0 # bottom margin
set multiplot
# Ausgabe oberer Graph
set size 1.000, 0.550 # Groesse der Grafik
set origin 0.000, 0.450 # def. der linken unteren Ecke
unset xlabel
plot $WHO_data usi 1:6 axis x1y1 tit 'Infizierte' lt rgb '#df7000' lw 1.75 with lines
# Ausgabe unterer Graph
set tmargin 0.4 # Wert von oben ueberschreiben damit Grafiken enger zusammen
unset bmargin # oben wurde bottommargin auf null gesetzt - jetzt wieder auto damit Platz fuer Skala
unset label #
set size 1.000, 0.450
set origin 0.000, 0.000
# Wenn das Datumsintervall so gross wird das die Labels zu eng gesetzt sind
# hier jeden zweiten Eintrag loeschen!
set xtics rotate by +30 center offset -1.5,-0.6
set xtics add ( " 2020" "2020-01-01" \
, "1. Feb." "2020-02-01" \
, "1. März" "2020-03-01" \
, "1. Apr." "2020-04-01" \
, "1. Mai" "2020-05-01" \
, "1. Jun." "2020-06-01" \
, "1. Jul." "2020-07-01" \
, "1. Aug." "2020-08-01" \
, "1. Sep." "2020-09-01" \
, "1. Okt." "2020-10-01" \
, "1. Nov." "2020-11-01" \
, "1. Dez." "2020-12-01" \
, " 2021" "2021-01-01" \
, "1. Feb." "2021-02-01" \
, "1. März" "2021-03-01" \
)
set xlabel "Datum (Monats- und KW-Skala)"
set yrange [-1:5]
set ytics 5
set mytics 5
# Ueber den Wert von lw kann man die Sichtbarkeit bei kl. Aufl. regulieren
plot $WHO_data usi 1:5 axis x1y1 tit '' lt rgb '#df7000' lw 0.75 with impulses
unset multiplot
|
Лицензирование
Я, владелец авторских прав на это произведение, добровольно публикую его на условиях следующей лицензии:
Этот файл доступен на условиях Creative Commons CC0 1.0 Универсальной передачи в общественное достояние (Universal Public Domain Dedication). | |
Лица, связанные с работой над этим произведением, решили передать данное произведение в общественное достояние, отказавшись от всех прав на произведение по всему миру в рамках закона об авторских правах (а также связанных и смежных прав), в той степени, которую допускает закон. Вы можете копировать, изменять, распространять, исполнять данное произведение в любых целях, в том числе в коммерческих, без получения на это разрешения автора.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Элементы, изображённые на этом файле
изображённый объект
image/svg+xml
97946a68f1e0f5d1b411bf9fb9d47c138dddef01
475 822 байт
450 пиксель
800 пиксель
История файла
Нажмите на дату/время, чтобы посмотреть файл, который был загружен в тот момент.
(новейшие | старейшие) Просмотреть (10 более новых | 10 более старых) (10 | 20 | 50 | 100 | 250 | 500)
Дата/время | Миниатюра | Размеры | Участник | Примечание | |
---|---|---|---|---|---|
текущий | 14:03, 26 декабря 2023 | 800 × 450 (465 КБ) | Summer ... hier! | update | |
16:44, 30 октября 2023 | 800 × 450 (449 КБ) | Summer ... hier! | update | ||
07:39, 6 октября 2023 | 800 × 450 (443 КБ) | Summer ... hier! | update | ||
18:59, 6 сентября 2023 | 800 × 450 (435 КБ) | Summer ... hier! | update | ||
15:59, 24 августа 2023 | 800 × 450 (430 КБ) | Summer ... hier! | update | ||
09:59, 10 августа 2023 | 800 × 450 (427 КБ) | Summer ... hier! | update | ||
00:56, 3 августа 2023 | 800 × 450 (425 КБ) | Summer ... hier! | update | ||
11:57, 27 июля 2023 | 800 × 450 (423 КБ) | Summer ... hier! | update | ||
21:45, 26 июля 2023 | 800 × 450 (423 КБ) | Summer ... hier! | update | ||
12:33, 13 июля 2023 | 800 × 450 (419 КБ) | Summer ... hier! | update |
Использование файла
Следующая страница использует этот файл:
Глобальное использование файла
Данный файл используется в следующих вики:
- Использование в de.wikipedia.org
- Использование в fr.wikipedia.org
Метаданные
Файл содержит дополнительные данные, обычно добавляемые цифровыми камерами или сканерами. Если файл после создания редактировался, то некоторые параметры могут не соответствовать текущему изображению.
Краткое название | COVID_19_12_2023_NR |
---|---|
Название изображения | Produced by GNUPLOT 5.0 patchlevel rc2 |
Ширина | 800 |
Высота | 450 |