Это изображение было создано с помощью Persistence of Vision.

Краткое описание

Лицензирование

Я, владелец авторских прав на это произведение, передаю его в общественное достояние. Это разрешение действует по всему миру. В некоторых странах это не может быть возможно юридически, в таком случае: Я даю право кому угодно использовать данное произведение в любых целях без каких-либо условий, за исключением таких условий, которые требуются по закону.

Source

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing.

#include "colors.inc"
     
background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -25>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5
  }


light_source
  {
  <0, 20, -50>
  color White
  area_light <5, 0, 0>, <0, 5, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }


#declare r_tube = 0.075;  // thickness (radius) of tube
#declare num_steps = 40;  // number of spline points
#declare step_size = 1/num_steps;

sphere_sweep
  {
  cubic_spline num_steps+3,
  #declare N = -1;
  #while(N <= num_steps + 1)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( (7/3)*sin(2*theta)-(2/3)*sin(3*theta) ), 0.3*( (7/3)*cos(2*theta)+(2/3)*cos(3*theta) ), 0.3*sin(5*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.25,1> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  }
              
plane
  {
  <0,0,-1>, -0.375
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }